<%
'定义分页显示函数DecoPage(rs,page_size,link)
'功能:分页
'参数描述:rs 要分页的游标, page_size 页面大小, link 链接地址
'设计人:郭兵
'最后修改时间:2004.4.25
function DecoPage(rs,page_size,link)
    dim page_count,nTemp
    if rs.eof and rs.bof then
        response.write "<br><p align='center'><font size=4>暂 无 信 息</font></p>"
    else
        rs.pagesize=page_size
    	nowPage=request.querystring("page")
        if nowPage="" or not isnumeric(nowPage) then
	        nowPage=1
	    else
	        nowPage=cint(nowPage)
            if nowPage<1 or nowPage>rs.PageCount then
	            nowPage=1
	        end if
	    end if	  
        rs.absolutePage=nowPage   
        response.write("本栏目记录共有 <font color=red>"&rs.recordcount&"</font> 条信息,每页显示 <font color=red>"&page_size&"</font> 条,本页第 <font color=red>"&nowPage&"</font> 页")
        response.write"&nbsp;&nbsp;"
	    page_count=rs.PageCount
	    nTemp=1
	    response.write("[<a class=gbbai href='"&link&nTemp&"'>首 页</a>]")
        if nowPage>1 then
	        nTemp=nowPage-1
	        response.write "&nbsp;&nbsp;"
            response.write("[<a class=gbbai href='"&link&nTemp&"'>上一页</a>]")		
        end if
	    if nowPage<page_count then
            nTemp=nowPage+1
            response.write "&nbsp;&nbsp;"
            response.write("[<a class=gbbai href='"&link&nTemp&"'>下一页</a>]")
	    end if
        nTemp=page_count 
	    response.write "&nbsp;&nbsp;"  
        response.write("[<a class=gbbai href='"&link&nTemp&"'>尾  页</a>]")
    end if
end function
%>