<!--#include file="../../Inc/Cls_Main.Asp"-->
<!--#include file="../inc/Cls_Admin.Asp"-->
<!--#include file="../inc/Cls_MapPath.Asp"-->
<!--#include file="../inc/Cls_InType.Asp"-->
<!--#include file="../Admin_Check.Asp"-->
<%
Dim CmsAdmin
'=============================================================================
Set CmsAdmin = New Cls_Admin
CmsAdmin.SetAdminTitle = CmsSiteName
CmsAdmin.SetBodyCssName = "mainbody"
CmsAdmin.SetAdminPath = CmsAdminMapPath
CmsAdmin.LoadHead()
'=============================================================================
Dim Action
'=============================================================================
Action = Easp.Get("action")
Select Case Action
    Case "pageload"
        Call PageLoad()
    Case "px"
        Call Px()
    Case "delall"
        Call DelAll()
    Case Else
        Call PageLoad()
End Select
CmsAdmin.LoadFooter()
Set CmsAdmin = Nothing

Sub PageLoad()
    ChkSysAdminLevel "sys_channel", "show"
    '=====================================================================
    Dim Keywords, ClassId
    Keywords = Easp.Get("Keywords:s")
    ClassId = Easp.Get("ClassId:n:0")
%>
<div class="navigation"><a href="Admin.Index.Asp" class="back">系统频道管理</a>控制面板 &gt; 系统频道管理 &gt; 属性管理</div>
<div class="tools_box">
  <div class="tools_bar">
    <ul>
      <li><a href="Admin.Attr.Type.List.Asp" class="tools_btn"><span><b class="return">类别管理</b></span></a></li>
      <li><a href="Admin.Attr.Add.Asp" class="tools_btn"><span><b class="add">添加属性</b></span></a></li>
      <li><a class="tools_btn" href="javascript:GetSubmit('myform','?action=px')"><span><b class="send">保存排序</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="checkAll(this);" class="tools_btn"><span><b class="all">全选</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="return ExePostBack('确定要批量删除吗？','myform','?action=delall');" class="tools_btn"><span><b class="delete">批量删除</b></span></a></li>
      <li><a href="Admin.Attr.List.Asp" class="tools_btn"><span><b class="refresh">刷新列表</b></span></a></li>
    </ul>
  </div>
  <div class="select_box">
    <form id="searchType" action="" method="get">
      <%=GetAttrType("选择类别", "ClassId", ClassId, "")%>
      <input name="Keywords" type="text" id="Keywords" class="txtInput w200" autocomplete="off" value="<%=Keywords%>" />
      <input type="submit" value="搜索" class="btnSearch" />
    </form>
  </div>
</div>
<form id="myform" action="?action=px" method="post">
  <table width="100%" border="0" cellspacing="0" cellpadding="0" class="msgtable">
    <tr>
      <th width="5%">选择</th>
      <th width="30%" align="left">名称</th>
      <th width="20%">所属类别</th>
      <th width="15%">排序</th>
      <th width="10%">添加时间</th>
      <th width="10%">操作</th>
    </tr>
    <%
    Dim ShowPage, oRs, PageNum, ArrayList, i, oSQL, TempWhere, FieldList
    ShowPage = ""
    PageNum = 20
    '============================ search
    TempWhere = " 1 = 1 "
    If Not Easp.IsN(Keywords) Then
        TempWhere = TempWhere & " And Title Like '%"& Keywords &"%' "
    End If
    If ClassId > 0 Then
        TempWhere = TempWhere & " And ClassId = "& ClassId &" "
    End If
    '============================ page
    Easp.db.PageSize = PageNum
    Easp.db.SetPager "default", "<span class=""disableds"">总记录数:{recordcount},每页:{pagesize},页次:{pageindex}/{pagecount}</span> {first}{prev}{list}{next}{last}{jump}", Array("first:首　页", "last:尾　页", "prev:上一页", "next:下一页", "list:*")
    '============================ data
    FieldList = "Id,AttrName,Px,AddTime,CnName"
    Set oRs = Easp.db.GPR("0", Array(TablePrefix & "Attr_View:" & FieldList, TempWhere, " Px Asc,Id desc ", " Id "))
    If Easp.IsN(oRs) Then
        Easp.C(oRs)
    Else
        ShowPage = Easp.db.GetPager("default")
        ArrayList = oRs.GetRows(PageNum)
    End If
    Easp.C oRs
    If IsArray(ArrayList) Then
        For i = 0 To UBound(ArrayList, 2)
    %>
    <tr align="center">
      <td><input type="checkbox" name="chkId" value="<%=ArrayList(0,i)%>" /></td>
      <td align="left"><%=ArrayList(1,i)%></td>
      <td><%=ArrayList(4,i)%></td>
      <td><input type="hidden" name="hidId" value="<%=ArrayList(0,i)%>" />
        <input type="text" class="txtInput2 w50" name="Px" value="<%=ArrayList(2,i)%>" maxlength="5" onfocus="ChkNumEric(this)" autocomplete="off" /></td>
      <td><%=CmsFun.TimeToString(ArrayList(3,i),"yyyy-mm-dd")%></td>
      <td><a href="Admin.Attr.Edit.Asp?id=<%=ArrayList(0,i)%>">编辑</a></td>
    </tr>
    <%
        Next
    End If
    %>
  </table>
  <div class="line15"> </div>
  <div class="page_box">
    <div class="flickr right"><%=ShowPage%></div>
  </div>
</form>
<%
End Sub

Sub Px()
    ChkSysAdminLevel "sys_channel", "edit"
    '=====================================================================
    Dim hidId, Px, i, spHidId, spPx
    hidId = Replace(Easp.Post("hidId:s"), ", ", ",")
    Px = Replace(Easp.Post("Px:s"), ", ", ",")
    If Easp.IsN(hidId) Then
        CmsAdmin.JscriptMsg "对不起，请选中您要操作的记录！", "back", "Error", "null"
    End If
    spHidId = Split(hidId, ",")
    spPx = Split(Px, ",")
    For i = 0 To UBound(spHidId)
        Easp.db.UR TablePrefix & "Attr", " Id = "& spHidId(i) &" ", Array("px:" & spPx(i))
    Next
    CmsAdmin.JscriptMsg "批量排序成功！", "Admin.Attr.List.Asp", "Success", "null"
End Sub

Sub DelAll()
    ChkSysAdminLevel "sys_channel", "del"
    '=====================================================================
    Dim chkId, ResultVal
    chkId = Easp.Post("chkId:s")
    If Easp.IsN(chkId) Then
        CmsAdmin.JscriptMsg "对不起，请选中您要操作的记录！", "back", "Error", "null"
    Else
        ResultVal = Easp.db.DR(TablePrefix & "Attr", "id:" & chkId)
        If ResultVal <> 0 Then
            CmsAdmin.JscriptMsg "批量删除成功！", "Admin.Attr.List.Asp", "Success", "null"
        End If
    End If
End Sub
%>
