<!--#include file="../../Inc/Cls_Main.Asp"-->
<!--#include file="../inc/Cls_Admin.Asp"-->
<!--#include file="../inc/Cls_MapPath.Asp"-->
<!--#include file="../inc/Cls_InType.Asp"-->
<!--#include file="../Admin_Check.Asp"-->
<%
Dim CmsAdmin, ToUrl
ToUrl = CmsFun.LoadToUrl()
'=============================================================================
Set CmsAdmin = New Cls_Admin
CmsAdmin.SetAdminTitle = CmsSiteName
CmsAdmin.SetBodyCssName = "mainbody"
CmsAdmin.SetAdminPath = CmsAdminMapPath
CmsAdmin.LoadHead()
'=============================================================================
Dim Action
'=============================================================================
Action = Easp.Get("action")
Select Case Action
    Case "pageload"
        Call PageLoad()
    Case "chk"
        Call ChkData()
    Case "delall"
        Call DelAll()
    Case Else
        Call PageLoad()
End Select
CmsAdmin.LoadFooter()
Set CmsAdmin = Nothing

Sub PageLoad()
    ChkSysAdminLevel "sys_book", "show"
    '=========================================================================
    Dim ClassId, Keywords
    ClassId = Easp.Get("ClassId:n:0")
    Keywords = Easp.Get("Keywords:s")
%>
<div class="navigation"><a href="Admin.Type.List.Asp" class="back">分类管理</a> 插件管理 &gt; 留言管理</div>
<div class="tools_box">
  <div class="tools_bar">
    <ul>
      <li><a href="javascript:void(0);" onclick="checkAll(this);" class="tools_btn"><span><b class="all">全选</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="return ExePostBack('确定要批量删除吗？','myform','?action=delall');" class="tools_btn"><span><b class="delete">批量删除</b></span></a></li>
      <li><a href="javascript:void(0);" onclick="return ExePostBack('确定要批量审核吗？','myform','?action=chk');" class="tools_btn"><span><b class="send">批量审核</b></span></a></li>
      <li><a href="Admin.Index.Asp" class="tools_btn"><span><b class="refresh">刷新列表</b></span></a></li>
    </ul>
  </div>
  <div class="select_box">
    <form id="searchType" action="" method="get">
    <%=GetBookType(ClassId,"")%>
      <input name="Keywords" type="text" id="Keywords" class="txtInput w200" autocomplete="off" value="<%=Keywords%>" />
      <input type="submit" value="搜索" class="btnSearch" />
    </form>
  </div>
</div>
<form id="myform" action="?action=chk" method="post">
  <table width="100%" border="0" cellspacing="0" cellpadding="0" class="msgtable">
    <tr>
      <th width="5%">选择</th>
      <th width="25%" align="left">主题</th>
      <th width="10%">分类</th>
      <th width="10%" align="left">留言人</th>
      <th width="10%" align="left">电话</th>
      <th width="10%">状态</th>
      <th width="10%">回复状态</th>
      <th width="10%">时间</th>
      <th width="10%">操作</th>
    </tr>
    <%
    Dim ShowPage, oRs, PageNum, ArrayList, i, oSQL, TempWhere, FieldList
    ShowPage = ""
    PageNum = 20
    '============================ search
    TempWhere = " 1 = 1 "
    If Not Easp.IsN(Keywords) Then
        TempWhere = TempWhere & " And Title Like '%"& Keywords &"%' "
    End If
    If ClassId > 0 Then
        TempWhere = TempWhere & " And ClassId = " & ClassId & " "
    End If
    '============================ page
    Easp.db.PageSize = PageNum
    Easp.db.SetPager "default", "<span class=""disableds"">总记录数:{recordcount},每页:{pagesize},页次:{pageindex}/{pagecount}</span> {first}{prev}{list}{next}{last}{jump}", Array("first:首　页", "last:尾　页", "prev:上一页", "next:下一页", "list:*")
    '============================ data
    FieldList = "Id,Title,CnName,UserName,Tel,IsChk,IsReply,AddTime"
    Set oRs = Easp.db.GPR("0", Array(TablePrefix & "Book_View:" & FieldList, TempWhere, " Id desc ", " Id "))
    If Easp.IsN(oRs) Then
        Easp.C(oRs)
    Else
        ShowPage = Easp.db.GetPager("default")
        ArrayList = oRs.GetRows(PageNum)
    End If
    Easp.C oRs
    If IsArray(ArrayList) Then
        For i = 0 To UBound(ArrayList, 2)
    %>
    <tr align="center">
      <td><input type="checkbox" name="chkId" value="<%=ArrayList(0,i)%>" /></td>
      <td align="left"><%=ArrayList(1,i)%></td>
      <td><%=ArrayList(2,i)%></td>
      <td align="left"><%=ArrayList(3,i)%></td>
      <td align="left"><%=ArrayList(4,i)%></td>
      <td><%=Easp.IIF(ArrayList(5,i) = 1,"已审核",CmsFun.ShowColor("未审核","red"))%></td>
      <td><%=Easp.IIF(ArrayList(6,i) = 1,"已回复",CmsFun.ShowColor("未回复","blue"))%></td>
      <td><%=CmsFun.TimeToString(ArrayList(7,i),"yyyy-mm-dd")%></td>
      <td><a href="Admin.Reply.Asp?id=<%=ArrayList(0,i)%>">回复</a></td>
    </tr>
    <%
        Next
    End If
    %>
  </table>
  <div class="line15"> </div>
  <div class="page_box">
    <div class="flickr right"><%=ShowPage%></div>
  </div>
</form>
<%
End Sub

Sub ChkData()
    ChkSysAdminLevel "sys_book", "audit"
    '=========================================================================
    Dim chkId
    chkId = Replace(Easp.Post("chkId:s"), ", ", ",")
    If Easp.IsN(chkId) Then
        CmsAdmin.JscriptMsg "对不起，请选中您要操作的记录！", "back", "Error", "null"
    End If
    Easp.db.UR TablePrefix & "Book", " Id in("& chkId &") ", Array("IsChk:1")
    CmsAdmin.JscriptMsg "批量审核成功！", ToUrl, "Success", "null"
End Sub

Sub DelAll()
    ChkSysAdminLevel "sys_book", "del"
    '=========================================================================
    Dim chkId, ResultVal
    chkId = Easp.Post("chkId:s")
    If Easp.IsN(chkId) Then
        CmsAdmin.JscriptMsg "对不起，请选中您要操作的记录！", "back", "Error", "null"
    Else
        ResultVal = Easp.db.DR(TablePrefix & "Book", "Id:" & chkId)
        If ResultVal <> 0 Then
            CmsAdmin.JscriptMsg "批量删除成功！", ToUrl, "Success", "null"
        End If
    End If
End Sub
%>
