1 COMMON A, AL, B, BASEONLY, C, C$, C1, CAT$, CC, CKT$, D, D$, DD, DIA, DIMN$, DMS, E, EO, EX$, F, F$, FD, FF, FQ, FRQ, G$, GO$, I, I$, L, LATLONG, LD, LL, LN, LS, LW, LX, MAX, MENU, MIN, MX, N, NN, NT, OV, P, PI, PROG$, Q, QQ, QU, R, RA, RC, T, T$, U, U$, UH, UL$, V$, VC, W, WHIP, WIRD, WW, X, X$, X1, XS, Z$, ZP, ZS
5 'OMMON EX$
10 'TORQUE : 5 DEC 85  rev. 22 MAR 2000
20 IF EX$=""THEN EX$="exit"
30 
40 CLS:KEY OFF
50 COLOR 7,0,4
60 U$="####,###.##"
70 UL$=STRING$(80,205)
80 GOTO 130
90 '
100 C1=5:C2=10:C3=41
110 FOR U=C1 TO C2:LOCATE U,C3:PRINT STRING$(40,32):NEXT U:RETURN
120 '
130 '.....start
140 CLS:COLOR 11,1,4
150 PRINT " TORQUE & HORSEPOWER";TAB(57);;"by George Murphy VE3ERP ";
160 COLOR 4,0:PRINT STRING$(80,"ß");
170 COLOR 7,0
180 PRINT TAB(24);"  Press letter in ( ) to select program";
190 PRINT UL$;
200 PRINT TAB(19);"  (a)  Torque, horsepower & RPM program";
210 PRINT TAB(19);"  (b)  Exit";
220 Z$=INKEY$
230 IF V<>0 THEN GOSUB 100:GOSUB 570
240 IF Z$="a"OR Z$="A"THEN CLS:GOTO 300
250 IF Z$="b"OR Z$="B"THEN CHAIN"mechmenu"
260 ON ERROR GOTO 280
270 GOTO 220
280 CLS:PRINT "error";ERR;;"in line";ERL:END
290 '
300 CLS:COLOR 7,0,0:LN=3:PRINT "TORQUE, H.P. & R.P.M. SPECIFICATIONS"
310 P=3.141592/12
320 LOCATE 1,41
330 PRINT "ENTER factors if known or";
340 LOCATE 2,41
350 PRINT "Press [ENTER] if unknown.";
360 IF R THEN 390
370 LOCATE 5,41:INPUT "R.P.M. ....................";R
380 IF R<>0 THEN GOSUB 100:GOSUB 570
390 IF D THEN 420
400 LOCATE 5,41:INPUT "Pitch dia.(gear/sprkt.) ...";D
410 IF D<>0 THEN GOSUB 100:GOSUB 570
420 IF T THEN 450
430 LOCATE 5,41:INPUT "Torque (in.lb.) ...........";T
440 IF T<>0 THEN GOSUB 100:GOSUB 570
450 IF H THEN 480
460 LOCATE 5,41:INPUT "Horsepower ................";H
470 IF H<>0 THEN GOSUB 100:GOSUB 570
480 IF W THEN 510
490 LOCATE 5,41:INPUT "Force in lb.(belt/chain tension) ";W
500 IF W<>0 THEN GOSUB 100:GOSUB 570
510 IF V THEN 540
520 LOCATE 5,41:INPUT "Velocity (feet/min.) ......";V
530 IF V<>0 THEN GOSUB 100:GOSUB 570
540 IF R*D*T*H*W*V THEN 860
550 GOTO 360
560 '
570 FOR Y=1 TO 7
580 IF V>0 AND V1=0 THEN V1=1:Z=V:A$="Velocity (ft./min.) ":GOSUB 780:GOTO 760
590 IF D*R THEN V=P*D*R
600 IF R>0 AND R1=0 THEN R1=1:Z=R:A$="R.P.M. ":GOSUB 780:GOTO 760
610 IF D*V THEN R=V/P/D
620 IF D>0 AND D1=0 THEN D1=1:Z=D:A$="Pitch diameter ":GOSUB 780:GOTO 760
630 IF V*R THEN D=V/P/R
640 IF T>0 AND T1=0 THEN T1=1:Z=T:A$="Torque (in.lb.) ":GOSUB 780:GOTO 690
650 IF W*D THEN T=W*D/2
660 IF H THEN 680
670 IF W*V THEN H=W*V/3.300000E+04
680 IF H>0 AND H1=0 THEN H1=1:Z=H:A$="Horsepower ":GOSUB 780 :GOTO 760
690 IF T*R THEN H=T*R/6.302500E+04
700 IF T THEN 720
710 IF H*R THEN T=6.302500E+04*H/R
720 IF W>0 AND W1=0 THEN W1=1:Z=W:A$="Force / Tension (lb.) ":GOSUB 780:GOTO 760
730 IF H*V THEN W=3.300000E+04*H/V
740 IF R THEN 760
750 IF H*T THEN R=6.302500E+04*H/T
760 NEXT Y:RETURN
770 '
780 LN=LN+1:LOCATE LN,1
790 PRINT TAB(26);USING U$;Z
800 LOCATE LN,1
810 PRINT STRING$(26,46)
820 LOCATE LN,1
830 PRINT A$;
840 RETURN
850 '
860 C1=1:C2=2:C3=41:GOSUB 110
870 '
880 '.....end
890 GOSUB 910:GOTO 130
900 '
910 'PRT
920 KEY OFF:GOSUB 990:LOCATE 25,5:COLOR 0,2
930 PRINT " Send this page to:(1)Printer Queue? (2)Printout? ";
940 PRINT "(3)Next page? (1/2/3)";:COLOR 7,0
950 Z$=INKEY$:IF Z$<"1"OR Z$>"3"THEN 950 ELSE GOSUB 990
960 IF Z$="3"THEN RETURN
970 FOR I%=1 TO 24:FOR J%=1 TO 80:LPRINT CHR$(SCREEN(I%,J%));:NEXT J%:NEXT I%
980 IF Z$="2"THEN LPRINT CHR$(12) ELSE 920
990 LOCATE 25,1:PRINT STRING$(80,32);:RETURN
