1 COMMON A, AL, B, BASEONLY, C, C$, C1, CAT$, CC, CKT$, D, D$, DD, DIA, DIMN$, DMS, E, EO, EX$, F, F$, FD, FF, FQ, FRQ, G$, GO$, I, I$, L, LATLONG, LD, LL, LN, LS, LW, LX, MAX, MENU, MIN, MX, N, NN, NT, OV, P, PI, PROG$, Q, QQ, QU, R, RA, RC, T, T$, U, U$, UH, UL$, V$, VC, W, WHIP, WIRD, WW, X, X$, X1, XS, Z$, ZP, ZS
10 'BIGNUM
20 WIDTH 40
30 GOTO 740
40 '
50 'print bars
60 PRINT "     ":RETURN
70 PRINT " Û   ":RETURN
80 PRINT "  Û  ":RETURN
90 PRINT "   Û ":RETURN
100 PRINT " Û Û ":RETURN
110 PRINT " ÛÛÛ ":RETURN
120 '
130 'blank
140 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,60,60,60,60,60:NEXT K
150 RETURN
160 '
170 'zero
180 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,100,100,100,110:NEXT
190 RETURN
200 '
210 'one
220 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,80,80,80,80,80:NEXT
230 RETURN
240 '
250 'two
260 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,90,110,70,110:NEXT
270 RETURN
280 '
290 'three
300 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,90,110,90,110:NEXT
310 RETURN
320 '
330 'four
340 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,70,70,100,110,90:NEXT
350 RETURN
360 '
370 'five
380 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,70,110,90,110:NEXT
390 RETURN
400 '
410 'six
420 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,70,110,100,110:NEXT
430 RETURN
440 '
450 'seven
460 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,90,90,90,90:NEXT
470 RETURN
480 '
490 'eight
500 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,100,110,100,110:NEXT
510 RETURN
520 '
530 'nine
540 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,110,100,110,90,110:NEXT
550 RETURN
560 '
570 'colon
580 FOR K=1 TO 6:LOCATE Y+K,X:ON K GOSUB 60,60,80,60,80,60:NEXT
590 RETURN
600 '
610 'convert to big number
620 IF Z=-1 THEN GOSUB 130:RETURN
630 IF Z=0 THEN GOSUB 170:RETURN
640 IF Z=1 THEN GOSUB 210:RETURN
650 IF Z=2 THEN GOSUB 250:RETURN
660 IF Z=3 THEN GOSUB 290:RETURN
670 IF Z=4 THEN GOSUB 330:RETURN
680 IF Z=5 THEN GOSUB 370:RETURN
690 IF Z=6 THEN GOSUB 410:RETURN
700 IF Z=7 THEN GOSUB 450:RETURN
710 IF Z=8 THEN GOSUB 490:RETURN
720 IF Z=9 THEN GOSUB 530:RETURN
730 '
740 'start
750 CLS:LOCATE 1,1,0
760 COLOR 7,0,0:KEY OFF
770 GOSUB 1150
780 I=2
790 FOR Y=1 TO 16
800 CLR=Y:IF Y<2 THEN CLR=2
805 IF Y=4 THEN CLR=11
810 IF Y>15 THEN CLR=9
820 COLOR CLR,0
830 T$=LEFT$(TIME$,2):TI=VAL(T$)
840 IF TI<12 THEN M$="a.m."ELSE M$="p.m."
850 IF TI=0 THEN TI=24
860 IF TI>12 THEN TI=TI-12
870 TI$=STR$(TI):IF LEN(TI$)<3 THEN TI$=" "+TI$
880 A$=MID$(TI$,2,1)
890 B$=MID$(TI$,3,1)
900 C$=MID$(TIME$,4,1)
910 D$=MID$(TIME$,5,1)
920 E$=RIGHT$(TIME$,3)
930 F$=J$(ZZ)
940 X=I:Z=VAL(A$)
950 IF Z=0 THEN Z=-1
960 GOSUB 610
970 X=I+5:Z=VAL(B$):GOSUB 610
980 X=I+10:GOSUB 570
990 X=I+15:Z=VAL(C$):GOSUB 610
1000 X=I+20:Z=VAL(D$):GOSUB 610
1010 X=I+26:LOCATE Y+1,X:PRINT STRING$(12,32)
1020 LOCATE Y+2,X:PRINT STRING$(12,32)
1030 LOCATE Y+2,X:PRINT F$
1040 DA=VAL(MID$(DATE$,4,2))
1050 LOCATE Y+3,X:PRINT MO$;DA
1060 LOCATE Y+4,X:PRINT RIGHT$(DATE$,4)
1070 COLOR 0,15
1080 LOCATE Y+5,X:PRINT E$;" ";:COLOR 7,0:PRINT
1090 LOCATE Y+6,X:PRINT M$
1100 IF E$=RIGHT$(TIME$,3)THEN 1100
1110 Z$=INKEY$:IF Z$=""THEN 1120 ELSE COLOR 7,0,0:SCREEN 9:CLS:SYSTEM
1120 NEXT Y
1130 GOTO 750
1140 '
1150 'day of week
1160 M=VAL (LEFT$(DATE$,2))
1170 D=VAL (MID$(DATE$,4,2))
1180 Y=VAL (RIGHT$(DATE$,4))
1190 J$(1)="Sunday
1200 J$(2)="Monday
1210 J$(3)="Tuesday
1220 J$(4)="Wednesday
1230 J$(5)="Thursday
1240 J$(6)="Friday
1250 J$(7)="Saturday
1260 K=INT(6.000000E-01+(1/M))
1270 L=Y-K
1280 O=M+12*K
1290 P=L/100
1300 Z1=INT(P/4)
1310 Z2=INT(P)
1320 Z3=INT((5*L)/4)
1330 Z4=INT(13*(O+1)/5)
1340 ZZ=Z4+Z3-Z2+Z1+D-1
1350 ZZ=ZZ-(7*INT(ZZ/7))+1
1360 FOR W=1 TO 12
1370 READ MO$:IF W=M THEN RESTORE:GOTO 1390
1380 NEXT W
1390 RETURN
1400 DATA January,February,March,April,May,June
1410 DATA July,August,September,October,November,December
