animal$[] = [ "Rat" "Ox" "Tiger" "Rabbit" "Dragon" "Snake" "Horse" "Goat" "Monkey" "Rooster" "Dog" "Pig" ]
element$[] = [ "Wood" "Fire" "Earth" "Metal" "Water" ]
yingyang$[] = [ "Yang" "Yin" ]
animal_ch$[] = strchars "子丑寅卯辰巳午未申酉戌亥"
stem_ch$[] = strchars "甲乙丙丁戊己庚辛壬癸"
# 
proc get year . el$ an$ yy$ anch$ stch$ .
   idx = (year - 4) mod 10
   el$ = element$[idx div 2 + 1]
   stch$ = stem_ch$[idx + 1]
   idx = (year - 4) mod 12
   an$ = animal$[idx + 1]
   anch$ = animal_ch$[idx + 1]
   yy$ = yingyang$[year mod 2 + 1]
.
proc zodiac year . .
   get year el$ an$ yy$ anch$ stch$
   print year
   cycle = (year - 1983) mod1 60
   print "      " & el$ & " " & an$ & " " & yy$ & " " & cycle & "/60"
   print "      " & stch$ & anch$
   print ""
.
zodiac 1935
zodiac 1938
zodiac 1968
zodiac 1972
zodiac 1976
zodiac 1984
zodiac 2017
