10 PRINT "MADLIB STORY-WRITER BY DAVE AHL BASED ON A PROGRAM"
15 PRINT "ORIGINALLY WRITTEN BY HENRY GALLO, JOHN GLENN HS."\PRINT 
20 DIM A$(11),B$(5),C$(10)\RANDOMIZE 
30 PRINT "O.K.  WE'RE GOING TO WRITE SOME MAD-LIB STORIES"
40 PRINT "TOGETHER.  YOU SUPPLY THE WORDS, I SUPPLY THE PLOT."\PRINT 
60 PRINT "FIRST I NEED 11 ADJECTIVES.  ADJECTIVES MODIFY"
70 PRINT "A NOUN, E.G., RED, DIRTY, LARGE, ETC."
80 FOR I=1 TO 11\INPUT A$(I)\NEXT I
90 PRINT \PRINT "NOW I NEED 5 ADVERBS.  THEY MODIFY VERBS"
100 PRINT "AND END IN 'LY' (SLOWLY, GREEDILY, ETC.)"
110 FOR I=1 TO 5\INPUT B$(I)\NEXT I
120 PRINT \PRINT "O.K.  NOW 10 NOUNS, E.G., TELETYPE, INSECT, COAT, ETC."
130 FOR I=1 TO 10\INPUT C$(I)\NEXT I
140 PRINT \PRINT "HOW ABOUT TWO FIRST NAMES OF MEN";\INPUT D$\INPUT E$
160 PRINT "THE FIRST NAME OF A GIRL";\INPUT F$
170 PRINT "AND SOMEONE'S LAST NAME";\INPUT G$
180 PRINT "A GEOGRAPHICAL LOCATION";\INPUT H$
190 PRINT "A LIQUID";\INPUT I$
200 PRINT "AND FINALLY, AN EXCLAMATORY WORD OR TWO";\INPUT J$\PRINT 
220 PRINT "VERY GOOD!  WOULD YOU LIKE A NEWSPAPER AD (1),"
230 PRINT "A WESTERN (2), A STORY ABOUT THE ARMY (3), OR"
240 PRINT "A WATERBED (4).  WHICH ONE, 1, 2, 3, OR 4";\INPUT N\PRINT 
250 IF N>0 THEN IF N<5 THEN 270
260 PRINT "COME ON NOW -- 1, 2, 3, OR 4";\INPUT N\GOTO 250
270 FOR I=1 TO 6\PRINT\NEXT I\ON N GOTO 300,400,500,600
300 PRINT "               DAILY GRUNT CLASSIFIEDS"\PRINT 
310 PRINT "FOR SALE: 1957 SEDAN.  THIS ";A$(1);" CAR IS IN A ";A$(2)
320 PRINT "CONDITION. IT WAS FORMERLY OWNED BY A ";A$(3);" SCHOOL TEACHER"
330 PRINT "WHO ALWAYS DROVE IT ";B$(1);". THERE IS A ";A$(4);" ";C$(1);" IN"
340 PRINT "THE BACK SEAT. IT HAS A CHROME ";C$(2);" ON THE HOOD, A ";A$(5)
350 PRINT "PAINT JOB, ";A$(6);" TIRES AND THE BACK OPENS INTO A ";A$(7)
360 PRINT C$(3);". WILL CONSIDER TAKING A SLIGHTLY USED ";C$(4);" IN TRADE"
370 PRINT \PRINT "LOST: IN THE VICINITY OF ";H$;", A ";A$(8);" FRENCH"
380 PRINT "POODLE WITH ";A$(9);" HAIR AND A ";A$(10);" TAIL. IT ANSWERS"
385 PRINT "TO THE NAME OF ";F$;". WHEN LAST SEEN IT WAS CARRYING A"
390 PRINT C$(5);" IN ITS MOUTH. A ";A$(11);" REWARD IS OFFERED."\GOTO 700
400 PRINT "                 AN ADULT WESTERN"\PRINT 
410 PRINT "TEX ";G$;", THE MARSHALL OF ";D$;" CITY RODE INTO TOWN. HE"
420 PRINT "SAT ";B$(2);" IN THE SADDLE, READY FOR TROUBLE. HE KNEW THAT"
430 PRINT "HIS ";A$(1);" ENEMY, ";E$;" THE KID WAS IN TOWN. THE KID WAS"
440 PRINT "IN LOVE WITH TEX'S HORSE, ";F$;".  SUDDENLY THE KID CAME OUT"
450 PRINT "OF THE ";A$(7);" NUGGET SALOON."\PRINT 
460 PRINT "'DRAW TEX,' HE YELLED ";B$(3);"."\PRINT 
470 PRINT "TEX REACHED FOR HIS ";C$(4);", BUT BEFORE HE COULD GET IT"
475 PRINT "OUT OF HIS ";C$(5);" THE KID FIRED, HITTING TEX IN THE ";C$(6)
480 PRINT "AND THE ";C$(7);"."\PRINT 
485 PRINT "AS TEX FELL HE PULLED OUT HIS OWN ";C$(8);" AND SHOT THE KID"
490 PRINT INT(50*RND+3);"TIMES IN THE ";C$(9);". THE KID DROPPED IN A POOL"
492 PRINT "OF ";I$;"."\PRINT \PRINT "'";J$;",' TEX SAID, 'I HATED TO DO IT BUT"
495 PRINT "HE WAS ON THE WRONG SIDE OF THE ";C$(10);".'"\PRINT \GOTO 700
500 PRINT "IF YOU PLAN ON JOINING THE ARMY, HERE ARE SOME ";A$(11)
510 PRINT "HINTS THAT WILL HELP YOU BECOME A ";A$(10);" SOLDIER."\PRINT 
520 PRINT "THE ARMY IS MADE UP OF OFFICERS, NON-COMS AND ";C$(1);"S."
530 PRINT "YOU CAN RECOGNIZE AN OFFICER BY THE ";C$(2);"S ON HIS"
540 PRINT "SHOULDERS AND THE FUNNY-LOOKING ";C$(3);"S ON HIS CAP."
550 PRINT "WHEN YOU ADDRESS AN OFFICER, ALWAYS SAY ";C$(4);" AND SAY IT"
555 PRINT B$(5);".  IF YOU GET A ";A$(9);" HAIRCUT, KEEP YOUR ";C$(5);"S"
560 PRINT "SHINED, AND SEE THAT YOUR ";C$(6);" IS CLEAN AT ALL TIMES,"
565 PRINT "YOU WILL BE A CREDIT TO THE SLOGAN:"\PRINT 
570 PRINT "            THE ARMY BUILDS BETTER ";C$(7);"S!"\PRINT 
575 PRINT "AT ROLL CALL, WHEN THE ";A$(8);" SERGEANT CALLS YOUR NAME,"
580 PRINT "SHOUT '";J$;"' LOUD AND CLEAR."\PRINT 
585 PRINT "YOU WILL BECOME FAMILIAR WITH WEAPONS LIKE THE .30 CALIBRE"
590 PRINT C$(8);" AND THE AUTOMATIC ";C$(9);"."\PRINT 
592 PRINT "FOLLOW THIS ADVICE AND YOU MAY WIN THE......"
595 PRINT "********** ";A$(7);" CONDUCT ";C$(10);" **********"\GOTO 700
600 PRINT "BUST-A-BUTTON AND DUCK DEPT. STORE"\PRINT "DIX HILLS, NEW YORK"
610 PRINT \PRINT "DEAR SIRS:"\PRINT 
620 PRINT "LAST WEEK I PURCHASED A ";A$(2);" CONTOUR WATER BED IN YOUR"
630 PRINT "STORE. I GOT IT ESPECIALLY FOR MY ";A$(4);" HUSBAND WHO SLEEPS"
640 PRINT "VERY ";B$(1);" AND SAYS THAT ";A$(6);" WATER BEDS THAT HAVE"
650 PRINT C$(1);"S IN THEM MAKE HIS ";C$(3);" ACHE. WHEN THE BED"
655 PRINT "ARRIVED MY HUSBAND TESTED IT ";B$(2);" AND SAID THE ";A$(8)
660 PRINT C$(5);" WAS BENT AND KEPT PRESSING INTO HIS ";C$(6);". HE SAYS"
665 PRINT "THIS COULD LEAD TO A ";A$(10);" CONDITION OF THE ";C$(8);"."\PRINT 
670 PRINT "I WOULD LIKE TO EXCHANGE THIS ";A$(9);" BED FOR ONE THAT"
675 PRINT "WILL ALLOW MY HUSBAND TO SLEEP ";B$(4);" AND WON'T MAKE"
680 PRINT "HIS ";C$(10);" SORE."\PRINT \PRINT TAB(30);"YOURS ";B$(5);","
690 PRINT TAB(30);F$;" ";G$\PRINT 
700 FOR I=1 TO 6\PRINT\NEXT I\PRINT "WANT ANOTHER STORY (YES OR NO)";\INPUT Y$
710 IF Y$="NO" THEN 900
720 PRINT "WANT TO USE THE SAME WORDS (YES OR NO)";\INPUT Y$\PRINT 
730 IF Y$="YES" THEN 220
731 IF Y$="NO" THEN 60
740 PRINT "COME ON NOW -- 'YES' OR 'NO'";\INPUT Y$\PRINT \GOTO 730
900 PRINT \PRINT "O.K.  SEE YOU AGAIN SOMETIME!"
999 END 
