# $Id$
# Maintainer: Qurban Ullah <qurbanullah@avouch.org>
# Contributor: Qurban Ullah <qurbanullah@avouch.org>

pkgname=texlive-science
pkgver=2017.44906
_revnr=${pkgver#2017.}
pkgrel=1
pkgdesc="TeX Live - Typesetting for mathematics, natural and computer sciences"
license=('GPL')
arch=(any)
depends=('texlive-core')
optdepends=('python2-pygments: for pygmentex')
groups=('devel')
repo=('extra')
url='http://tug.org/texlive/'
source=("https://sources.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip"
        "$pkgname.maps"
        "$pkgname.fmts")
options=('!emptydirs')
sha256sums=('698e2f3e2bf16b275e9b5be6b0114b68d704b58b1e911e9594c96ab3f7b75892'
            '1d9151c9cabc3521b4406731b0147d80e0bf600bdedaf55a1a49b8775165daa8'
            '1cbd5339f8cfa32214a749a408cf7136fd5acffaffcde6500a337d332c70c5c3')

build() {
    cd "$srcdir"
    bsdtar -xf ${pkgname}-${pkgver}-src.zip
    for p in *.tar.xz; do
        bsdtar -xf $p
    done
   rm -rf {tlpkg,doc,source} || true
}

package() {
   cd "$srcdir"
   install -m755 -d $pkgdir/var/lib/texmf/avouch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/avouch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 $pkgname.maps $pkgdir/var/lib/texmf/avouch/installedpkgs/
   install -m644 $pkgname.fmts $pkgdir/var/lib/texmf/avouch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   install -m755 -d $pkgdir/usr/bin
   ln -s /usr/share/texmf-dist/scripts/pygmentex/pygmentex.py $pkgdir/usr/bin/pygmentex
   ln -s /usr/share/texmf-dist/scripts/ulqda/ulqda.pl $pkgdir/usr/bin/ulqda
}
