# $Id$
# Maintainer: Qurban Ullah <qurbanullah@avouch.org>
# Contributor: Qurban Ullah <qurbanullah@avouch.org>

pkgname=texlive-music
pkgver=2017.44885
_revnr=${pkgver#2017.}
pkgrel=1
pkgdesc="TeX Live - Music typesetting packages"
license=('GPL')
arch=(any)
depends=('texlive-core')
optdepends=('python2: for scripts from the lilyglyphs packages')
groups=('devel')
repo=('extra')
url='http://tug.org/texlive/'
source=("https://sources.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip" "$pkgname.maps")
options=('!emptydirs')
sha256sums=('99b631f5d8b3bee474a27ee21eb7a10a7d56f8514ca48bb94665ec1953e2c804'
            '0b3cc045390e756eb9243c0acc99a48a9c02ddab4764f4a00f8c3170660f017f')

build() {
	cd "$srcdir"
	bsdtar -xf texlive-music-2017.44885-src.zip
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true
}

package() {
   install -m755 -d $pkgdir/var/lib/texmf/avouch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/avouch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 $pkgname.maps $pkgdir/var/lib/texmf/avouch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   # fix python2 command name in scripts.
   sed -i 's/env python/env python2/' $pkgdir/usr/share/texmf-dist/scripts/lilyglyphs/*.py
   # script symlinks
   install -m755 -d $pkgdir/usr/bin
   ln -s /usr/share/texmf-dist/scripts/lilyglyphs/lily-glyph-commands.py $pkgdir/usr/bin/lily-glyph-commands
   ln -s /usr/share/texmf-dist/scripts/lilyglyphs/lily-image-commands.py $pkgdir/usr/bin/lily-image-commands
   ln -s /usr/share/texmf-dist/scripts/lilyglyphs/lily-rebuild-pdfs.py $pkgdir/usr/bin/lily-rebuild-pdfs
   ln -s /usr/share/texmf-dist/scripts/m-tx/m-tx.lua $pkgdir/usr/bin/m-tx
   ln -s /usr/share/texmf-dist/scripts/musixtex/musixflx.lua $pkgdir/usr/bin/musixflx
   ln -s /usr/share/texmf-dist/scripts/musixtex/musixtex.lua $pkgdir/usr/bin/musixtex
   ln -s /usr/share/texmf-dist/scripts/pmxchords/pmxchords.lua $pkgdir/usr/bin/pmxchords
}
